MXML & dispatchEvent

[פלג]

יש לי MXML שקורא למתודה שנמצא ב CLASS.
ב CLASS המתודה קוראת ל WS ומחכה לתשובה אסינכרונית.
איך מהתשובה האסינכרונית אני שולח חזרה לפונקציה ב MXML את התוצאה?

Syntax: [ Download ] [ Hide ]

Syntax: [ Download ] [ Show ]

Using actionscript3 Syntax Highlighting

//step 1: call the function that will activate a WS
var objAccountManager:AccountManager=new AccountManager();
objAccountManager.GetEncryptedDecryptedPass("peleg","encrypt");
function getWsResult(){}
 

Parsed in 0.030 seconds, using GeSHi 1.0.8.4

Syntax: [ Download ] [ Hide ]

Syntax: [ Download ] [ Show ]

Using actionscript3 Syntax Highlighting

//step 2:
//how to send an event back from the class to the function getWsResult??
 

Parsed in 0.027 seconds, using GeSHi 1.0.8.4

[atarsh]

לפני שהמחלקה שמוגדרת ב-mxml (נקרא לה A בשביל הנוחות) קוראת לפונקציה על המחלקה הנוספת (נקרא לה B) שמתחילה את הפעולה הא-סינכרונית, תגרום למחלקה A להאזין לאירוע שמוגדר במחלקה B.
כשמחלקה B מקבלת את התשובה הא-סינכרונית שלה דספץ' את האיבנט, מחלקה B תשמע ותמשיך משם.
אם האיבנט הוא קאסטום אתה יכול ממש להעביר עליו את הdata המבוקש, אחרת אתה יכול להוסיף על מחלקה B איזשהו getter למידע הזה ומחלקה A תקרא לו בתגובה לאיבנט.

[פלג]

יש מצב לקוד דוגמא?

[atarsh]

השתמשתי בטעינת קובץ טקסט בתור הפעולה הא-סינכרונית שלי, אתה כמובן מוזמן לעשות מה שבא לך.
מחלקה A:

Syntax: [ Download ] [ Hide ]

Syntax: [ Download ] [ Show ]

Using actionscript3 Syntax Highlighting

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml"
                                xmlns:controls="com.kaltura.controls.*"
                                height="545" width="930" layout="vertical"
                                creationComplete="application1_creationCompleteHandler(event)">
        <mx:Script>
                <![CDATA[
                        import mx.events.FlexEvent;
                       
                        private var b:B;
                       
                        protected function application1_creationCompleteHandler(event:FlexEvent):void {
                                b = new B();
                                b.addEventListener("loadingComplete", onLoadComplete);
                        }
                       
                        private function onLoadComplete(e:Event):void {
                                trace (b.message);
                        }


                        protected function button1_clickHandler(event:MouseEvent):void
                        {
                                b.loadFile();
                        }

                ]]>
        </mx:Script>

        <mx:Button label="click me" click="button1_clickHandler(event)"/>
       
</mx:Application>

Parsed in 0.036 seconds, using GeSHi 1.0.8.4

מחלקה B:

Syntax: [ Download ] [ Hide ]

Syntax: [ Download ] [ Show ]

Using actionscript3 Syntax Highlighting

package
{
        import flash.events.Event;
        import flash.events.EventDispatcher;
        import flash.net.URLLoader;
        import flash.net.URLRequest;

        public class B extends EventDispatcher{
               
               
                public var message:String = '';
               
                private var ldr:URLLoader;
               
                public function B()
                {
                }
               
                public function loadFile():void {
                        var req:URLRequest = new URLRequest("file.txt");
                        ldr = new URLLoader();
                        ldr.addEventListener(Event.COMPLETE, onDataLoaded);
                        ldr.load(req);
                }
               
               
                private function onDataLoaded(e:Event):void {
                        message = e.target.data;
                        dispatchEvent(new Event("loadingComplete"));
                }
        }
}

Parsed in 0.033 seconds, using GeSHi 1.0.8.4

[פלג]

תודה, איך אני מרחיב את זה גם להעברת ערכים כחלק מה dispatchEvent?

[atarsh]

במקום להשתמש באיבנט גנרי אתה כותב מחלקה שמרחיבה את Event, ומוסיף לה פרמטרים.
איפה שאתה מדספץ' את האיבנט תמלא גם את הפרמטרים האלה, ובמקום שבו אתה תופס את האיבנט תשתמש בהם.

[פלג]

תודה

[atarsh]

בכיף